(Added a section on load/store pairs on June 14th)
This question probably seems absurd. An unoptimized memcpy is a simple loop that copies bytes. How hard can that be? Well...
There's a fascinating thread on llvm-dev started by George Mitenkov proposing a new family of "byte" types. I found the proposal and discussion difficult to follow. In my humble opinion, this is because the proposal touches some rather subtle and underspecified aspects of LLVM IR semantics, and rather than address those fundamentals systematically, it jumps right into the minutiae of the instruction set. I look forward to seeing how the proposal evolves. In the meantime, this article is a byproduct of me attempting to digest the problem space.
Here is a fairly natural way to (attempt to) implement memcpy in LLVM IR:
define void @memcpy(i8* %dst, i8* %src, i64 %n) {
entry:
%dst.end = getelementptr i8, i8* %dst, i64 %n
%isempty = icmp eq i64 %n, 0
br i1 %isempty, label %out, label %loop
loop:
%src.loop = phi i8* [ %src, %entry ], [ %src.next, %loop ]
%dst.loop = phi i8* [ %dst, %entry ], [ %dst.next, %loop ]
%ch = load i8, i8* %src.loop
store i8 %ch, i8* %dst.loop
%src.next = getelementptr i8, i8* %src.loop, i64 1
%dst.next = getelementptr i8, i8* %dst.loop, i64 1
%done = icmp eq i8* %dst.next, %dst.end
br i1 %done, label %out, label %loop
out:
ret void
}
Unfortunately, the copy that is written to the destination is not a perfect copy of the source.
Hold on, I hear you think, each byte of memory holds one of 256 possible bit patterns, and this bit pattern is perfectly copied by the `load`/`store` sequence! The catch is that in LLVM's model of execution, a byte of memory can in fact hold more than just one of those 256 values. For example, a byte of memory can be poison, which means that there are at least 257 possible values. Poison is forwarded perfectly by the code above, so that's fine. The trouble starts because of pointer provenance.
What and why is pointer provenance?
From a machine perspective, a pointer is just an integer that is interpreted as a memory address.
For the compiler, alias analysis -- that is, the ability to prove that different pointers point at different memory addresses -- is crucial for optimization. One basic tool in the alias analysis toolbox is to recognize that if pointers point into different "memory objects" -- different stack or heap allocations -- then they cannot alias.
Unfortunately, many pointers are obtained via getelementptr (GEP) using dynamic (non-constant) indices. These dynamic indices could be such that the resulting pointer points into a different memory object than the base pointer. This makes it nearly impossible to determine at compile time whether two pointers point into the same memory object or not.
Which is why there is a rule which says (among other things) that if a pointer P obtained via GEP ends up going out-of-bounds and pointing into a different memory object than the pointer on which the GEP was based, then dereferencing P is undefined behavior even though the pointer's memory address is valid from the machine perspective.
As a corollary, a situation is possible in which there are two pointers whose underlying memory address is identical but whose provenance is different. In that case, it's possible that one of them can be dereferenced while dereferencing the other is undefined behavior.
This only makes sense if, in the formal semantics of LLVM IR, pointer values carry more information than just an integer interpreted as a memory address. They also carry provenance information, which is essentially the set of memory objects that can be accessed via this pointer and any pointers derived from it.
Bytes in memory carry provenance information
What is the provenance of a pointer that results from a load instruction? In a clean operational semantics, the load must derive this provenance from the values stored in memory.
If bytes of memory can only hold one of 256 bit patterns (or poison), that doesn't give us much to work with. We could say that the provenance of the pointer is "empty", meaning the pointer cannot be used to access any memory objects -- but that's clearly useless. Or we could say that the provenance of the pointer is "all", meaning the pointer (or pointers derived from it) can be freely used to access all memory objects, assuming the underlying address is adjusted appropriately. That isn't much better.[0]
Instead, we must say that -- as far as LLVM IR semantics are concerned -- each byte of memory holds pointer provenance information in addition to its i8 content. The provenance information in memory is written by pointer store, and pointer load uses it to reconstruct the original provenance of the loaded pointer.
What happens to provenance information in non-pointer load/store? A load can simply ignore the additional information in memory. For store, I see 3 possible choices:
1. Leave the provenance information that already happens to be in memory unmodified.
2. Set the provenance to "empty".
3. Set the provenance to "all".
Looking back at our attempt to implement memcpy, there is no choice which results in a perfect copy. All of the choices lose provenance information.
Without major changes to LLVM IR, only the last choice is potentially viable because it is the only choice that allows dereferencing pointers that are loaded from the memcpy destination.
Should we care about losing provenance information?
Without major changes to LLVM IR, we can only implement a memcpy that loses provenance information during the copy.
So what? Alias analysis around memcpy and code like it ends up being conservative, but reasonable people can argue that this doesn't matter. The burden of evidence lies on whoever wants to make a large change here in order to improve alias analysis.
That said, we cannot just call it a day and go (or stay) home either, because there are related correctness issues in LLVM today, e.g. bug 37469 mentioned in the initial email of that llvm-dev thread.
Here's a simpler example of a correctness issue using our hand-coded memcpy:
define i32 @sample(i32** %pp) {
%tmp = alloca i32*
%pp.8 = bitcast i32** %pp to i8*
%tmp.8 = bitcast i32** %tmp to i8*
call void @memcpy(i8* %tmp.8, i8* %pp.8, i64 8)
%p = load i32*, i32** %tmp
%x = load i32, i32* %p
ret i32 %x
}
A transform that should be possible is to eliminate the memcpy and temporary allocation:
define i32 @sample(i32** %pp) {
%p = load i32*, i32** %pp
%x = load i32, i32* %p
ret i32 %x
}
This transform is incorrect because it introduces undefined behavior.
To see why, remember that this is the world where we agree that integer stores write an "all" provenance to memory, so %p in the original program has "all" provenance. In the transformed program, this may no longer be the case. If @sample is called with a pointer that was obtained through an out-of-bounds GEP whose resulting address just happens to fall into a different memory object, then the transformed program has undefined behavior where the original program didn't.
We could fix this correctness issue by introducing an unrestrict instruction which elevates a pointer's provenance to the "all" provenance:
define i32 @sample(i32** %pp) {
%p = load i32*, i32** %pp
%q = unrestrict i32* %p
%x = load i32, i32* %q
ret i32 %x
}
Here, %q has "all" provenance and therefore no undefined behavior is introduced.
I believe that (at least for address spaces that are well-behaved?) it would be correct to fold inttoptr(ptrtoint(x)) to unrestrict(x). The two are really the same.
For that reason, unrestrict could also be used to fix the above-mentioned bug 37469. Several folks in the bug's discussion stated the opinion that the bug is caused by incorrect store forwarding that should be weakened via inttoptr(ptrtoint(x)). unrestrict(x) is simply a clearer spelling of the same idea.
A dead end: integers cannot have provenance information
A natural thought at this point is that the situation could be improved by adding provenance information to integers. This is technically correct: our hand-coded memcpy would then produce a perfect copy of the memory contents.
However, we would get into serious trouble elsewhere because global value numbering (GVN) and similar transforms become incorrect: two integers could compare equal using the icmp instruction, but still be different because of different provenance. Replacing one by the other could result in miscompilation.
GVN is important enough that adding provenance information to integers is a no-go.
I suspect that the unrestrict instruction would allow us to apply GVN to pointers, at the cost of making later alias analysis more conservative and sprinkling unrestrict instructions that may inhibit other transforms. I have no idea what the trade-off is on that.
The "byte" types: accurate representation of memory contents
With all the above in mind, I can see the first-principles appeal of the proposed "byte" types. They allow us to represent the contents of memory accurately in SSA values, and so they fill a real gap in the expressiveness of LLVM IR.
That said, the software development cost of adding a whole new family of types to LLVM is very high, so it better be justified by more than just aesthetics.
Our hand-coded memcpy can be turned into a perfect copier with straightforward replacement of i8 by b8:
define void @memcpy(b8* %dst, b8* %src, i64 %n) {
entry:
%dst.end = getelementptr b8, b8* %dst, i64 %n
%isempty = icmp eq i64 %n, 0
br i1 %isempty, label %out, label %loop
loop:
%src.loop = phi b8* [ %src, %entry ], [ %src.next, %loop ]
%dst.loop = phi b8* [ %dst, %entry ], [ %dst.next, %loop ]
%ch = load b8, b8* %src.loop
store b8 %ch, b8* %dst.loop
%src.next = getelementptr b8, b8* %src.loop, i64 1
%dst.next = getelementptr b8, b8* %dst.loop, i64 1
%done = icmp eq b8* %dst.next, %dst.end
br i1 %done, label %out, label %loop
out:
ret void
}
Looking at the concrete choices made in the proposal, I disagree with some of them.
Memory should not be typed. In the proposal, storing an integer always results in different memory contents than storing a pointer (regardless of its provenance), and implicitly trying to mix pointers and integers is declared to be undefined behavior. In other words, a sequence such as:
store i64 %x, i64* %p
%q = bitcast i64* %p to i8**
%y = load i8*, i8** %q
... is undefined behavior under the proposal instead of being effectively inttoptr(%x). That seems fine for C/C++, but is it going to be fine for other frontends?
The corresponding distinction between bytes-as-integers and bytes-as-pointers complicates the proposal overall, e.g. it forces them to add a bytecast instruction.
Conversely, the benefits of the distinction are unclear to me. One benefit appears to be guaranteed non-aliasing between pointer and non-pointer memory accesses, but that is a form of type-based alias analysis which in LLVM should idiomatically be done via TBAA metadata. (Update: see the addendum for another potential argument in favor of typed memory.)
So let's keep memory untyped, please.
Bitwise poison in byte values makes me really nervous due to the arbitrary deviation from how poison works in other types. I don't see any justification for it in the proposal. I can kind of see how one could be motivated by implementing memcpy with vector intrinsics operating on, for example, <8 x b32>, but a simpler solution would be to just use <32 x b8> instead. And if poison is indeed bitwise, then certainly pointer provenance would also have to be bitwise!
Finally, no design discussion is complete without a little bit of bike-shedding. I believe the name "byte" is inspired by C++'s std::byte, but given that types such as b256 are possible, this name would forever be a source of confusion. Naming is hard, and I think we should at least try to look for a better one. Let me kick off the brainstorming by suggesting we think of them as "memory content" values, because that's what they are. The types could be spelled m8, m32, etc. in IR assembly.
A variation: adding a pointer provenance type
In the llvm-dev thread, Jeroen Dobbelaere points out work being done to introduce explicit `ptr_provenance` operands on certain instructions, in service of C99's restrict keyword. I haven't properly digested this work, but it inspired the thoughts of this section.
Values of the proposed byte types have both a bit pattern and a pointer provenance. Do we really need to have both pieces of information in the same SSA value? We could instead split them up into an integer bit pattern value and a pointer provenance value with an explicit provenance type. Loads of integers could read out the provenance information stored in memory and provide it as a secondary result. Similarly, stores of integers could accept the desired provenance to be stored in memory as a secondary data operand. This would allow us to write a perfect memcpy by replacing the core load/store sequence with something like:
%ch, %provenance = load_with_provenance i8, i8* %src
store_with_provenance i8 %ch, provenance %provenance, i8* %dst
The syntax and instruction names in the example are very much straw men. Don't take them too seriously, especially because LLVM IR doesn't currently allow multiple result values.
Interestingly, this split allows the derivation of pointer provenance to follow a different path than the calculation of the pointer's bit pattern. This in turn allows us in principle to perform GVN on pointers without being conservative for alias analysis.
One of the steps in bug 37469 is not quite GVN, but morally similar. Simplifying a lot, the original program sequence:
%ch1 = load i8, i8* %p1
%ch2 = load i8, i8* %p2
%eq = icmp eq i8 %ch1, %ch2
%ch = select i1 %eq, i8 %ch1, i8 %ch2
store i8 %ch, i8* %p3
... is transformed into:
%ch2 = load i8, i8* %p2
store i8 %ch2, i8* %p3
This is correct for the bit patterns being loaded and stored, but the program also indirectly relies on pointer provenance of the data. Of course, there is no pointer provenance information being copied here because i8 only holds a bit pattern. However, with the "byte" proposal, all the i8s would be replaced by b8s, and then the transform becomes incorrect because it changes the provenance information.
If we split the proposed use of b8 into a use of i8 and explicit provenance values, the original program becomes:
%ch1, %prov1 = load_with_provenance i8, i8* %p1
%ch2, %prov2 = load_with_provenance i8, i8* %p2
%eq = icmp eq i8 %ch1, %ch2
%ch = select i1 %eq, i8 %ch1, i8 %ch2
%prov = select i1 %eq, provenance %prov1, provenance %prov2
store_with_provenance i8 %ch, provenance %prov, i8* %p3
This could be transformed into something like:
%prov1 = load_only_provenance i8* %p1
%ch2, %prov2 = load_with_provenance i8, i8* %p2
%prov = merge provenance %prov1, %prov2
store_with_provenance i8 %ch2, provenance %prov, i8* %p3
... which is just as good for code generation but loses only very little provenance information.
Aside: loop idioms
Without major changes to LLVM IR, a perfect memcpy cannot be implemented because pointer provenance information is lost.
Nevertheless, one could still define the @llvm.memcpy intrinsic to be a perfect copy. This helps memcpys in the original source program be less conservative in terms of alias analysis. However, it also makes it incorrect to replace a memcpy loop idiom with a use of @llvm.memcpy: without adding unrestrict instructions, the replacement may introduce undefined behavior; and there is no way to bound the locations where such unrestricts may be needed.
We could augment @llvm.memcpy with an immediate argument that selects its provenance behavior.
In any case, one can argue that bug 37469 is really a bug in the loop idiom recognizer. It boils down to the details of how everything is defined, and unfortunately, these weird corner cases are currently underspecified in the LangRef.
Conclusion
We started with the question of whether memcpy can be implemented in LLVM IR. The answer is a qualified Yes. It is possible, but the resulting copy is imperfect because pointer provenance information is lost. This has surprising implications which in turn happen to cause real miscompilation bugs -- although those bugs could be fixed even without a perfect memcpy.
The "byte" proposal has a certain aesthetic appeal because it fixes a real gap in the expressiveness of LLVM IR, but its software engineering cost is large and I object to some of its details. There are also alternatives to consider.
The miscompilation bugs obviously need to be fixed, but they can be fixed much less intrusively, albeit at the cost of more conservative alias analysis in the affected places. It is not clear to me whether improving alias analysis justifies the more complex solutions.
I would like to understand better how all of this interacts with the C99 restrict work. That work introduces mechanisms for explicitly talking about pointer provenance in the IR, which may allow us to kill two birds with one stone.
In any case, this is a fascinating topic and discussion, and I feel like we're only at the beginning.
Addendum: storing back previously loaded integers
(Added this section on June 14th)
Harald van Dijk on Phrabricator and Ralf Jung on llvm-dev, referring to a Rust issue, explicitly and implicitly point out a curious issue with loading and storing integers.
Here is Harald's example:
define i8* @f(i8* %p) {
%buf = alloca i8*
%buf.i32 = bitcast i8** %buf to i32*
store i8* %p, i8** %buf
%i = load i32, i32* %buf.i32
store i32 %i, i32* %buf.i32
%q = load i8*, i8** %buf
ret i8* %q
}
There is a pair of load/store of i32 which is fully redundant from a machine perspective and so we'd like to optimize that away, after which it becomes obvious that the function really just returns %p -- at least as far as bit patterns are concerned.
define i8* @f(i8* %p) {
%buf = alloca i8*
%buf.i32 = bitcast i8** %buf to i32*
store i8* %p, i8** %buf
%i = load i32, i32* %buf.i32
store i32 %i, i32* %buf.i32
%q = unrestrict i8* %p
ret i8* %q
}
We can then dead-code eliminate the bulk of the function and obtain:
define i8* @f(i8* %p) {
%q = unrestrict i8* %p
ret i8* %q
}
... which is as good as it can possibly get.
So, there is a good chance that preventing this particular optimization is relatively cheap in terms of code quality, and the gain in overall design simplicity may well be worth it.
[0] We could also say that the loaded pointer's provenance is magically the memory object that happens to be at the referenced memory address. Either way, provenance would become a useless no-op in most cases. For example, mem2reg would have to insert unrestrict instructions (defined later) everywhere because pointers become effectively "unrestricted" when loaded from alloca'd memory.
